print()

描述

透過序列埠印出具有閱讀性的 ASCII 文字。這個函式有多種形式，你可以印出數字、符點數、字元或字串。請看以下範例：

• Serial.print(78) 會是 “78”
• Serial.print(1.23456) 會是 “1.23”
• Serial.print('N') 會是 “N”
• Serial.print("Hello world.") 會是 “Hello world.”

你可以使用第二個參數來指定格式 (此參數為非必需)；可用的格式有：BIN (二進位格式)、OCT (八進位格式)、DEC (十進位格式)、HEX (十六進位格式)。對於符點數，這個參數可以指定小數點後的位數，請看以下範例：

• Serial.print(78, BIN) 會是 “1001110”
• Serial.print(78, OCT) 會是 “116”
• Serial.print(78, DEC) 會是 “78”
• Serial.print(78, HEX) 會是 “4E”
• Serial.println(1.23456, 0) 會是 “1”
• Serial.println(1.23456, 2) 會是 “1.23”
• Serial.println(1.23456, 4) 會是 “1.2346”

若要送一個 byte，請使用 Serial.write()。

語法


Serial.print(val)
Serial.print(val, format)


參數

val: 要印的值 – 任意型別
format: 指定印出的格式 (對於整數的資料型別) 或小數點後的位數 (對於符點數資料型別)

回傳

size_t (long)：print() 的 byte 數

範例

/*
用 for 迴圈印出指定格式的資料
*/
int x = 0;    // 宣告變數

void setup() {
  Serial.begin(9600);      // 設定 Serial 為 9600 鮑率
}

void loop() {  
  Serial.print("NO FORMAT");       // 印一個標籤
  Serial.print("\t");              // 印一個 tab

  Serial.print("DEC");  
  Serial.print("\t");      

  Serial.print("HEX");
  Serial.print("\t");  

  Serial.print("OCT");
  Serial.print("\t");

  Serial.print("BIN");
  Serial.print("\t");

  for(x=0; x< 64; x++){    // 只印出 ASCII 表的一部分

    // 印出多種格式：
    Serial.print(x);       // 印出十進位的數字 - 等同於 "DEC"
    Serial.print("\t");    // 印一個 tab

    Serial.print(x, DEC);  // 印出十進位格式的數字
    Serial.print("\t");    // 印一個 tab

    Serial.print(x, HEX);  // 印出十六進位格式的數字
    Serial.print("\t");    // 印一個 tab

    Serial.print(x, OCT);  // 印出八進位格式的數字
    Serial.print("\t");    // 印一個 tab

    Serial.println(x, BIN);  // 印出二進位格式的數字
    //                             最後用 "println" 來換行
    delay(200);            // 延遲 200 毫秒
  }
  Serial.println("");      // 換行
}

提醒

序列埠傳輸屬於非同步傳輸。當 Serial.print() 返回時，硬體可能還沒送出任何字元。

See also

－ Serial
－ available()
－ begin()
－ end()
－ find()
－ findUntil()
－ flush()
－ parseFloat()
－ parseInt()
－ peek()
－ println()
－ read()
－ readBytes()
－ readBytesUntil()
－ setTimeout()
－ write()
－ serialEvent()

語法參考主頁面

The text of the 86Duino reference is a modification of the Arduino reference, and is licensed under a Creative Commons Attribution-ShareAlike 3.0 License. Code samples in the reference are released into the public domain.